val (eval) is a simple arbitrary precision calculator language built on top of chumsky and ariadne.

val should run on any system, including Linux, MacOS, and the BSDs.

The easiest way to install it is by using cargo, the Rust package manager:

Pre-built binaries for Linux, MacOS, and Windows can be found on the releases page.

The primary way to use val is via the provided command-line interface. There is currently ongoing work on a Rust library and web playground, which will provide a few extra ways to interact with the runtime.

Below is the output of val --help, which describes some of the arguments/options we support:

Usage: val [OPTIONS] [FILENAME]

Arguments:
  [FILENAME]

Options:
  -e, --expression <EXPRESSION>
  -h, --help                     Print help
  -V, --version                  Print version

Running val on its own will spawn a repl (read–eval–print loop) environment, where you can evaluate arbitrary val code and see its output immediately. We use rustyline for its implementation, and we support a few quality of life features:

• Syntax highlighting (see image above)
• Persistent command history
• Emacs-style editing support by default
• Filename completions
• Hints (virtual text pulled from history)

The val language supports not only expressions, but quite a few statements as well. You may want to save val programs and execute them later, so the command-line interface provides a way to evaluate entire files.

For instance, lets say you have the following val program at factorial.val:

fn factorial(n) {
  if (n <= 1) {
    return 1
  } else {
    return n * factorial(n - 1)
  }
}

println(factorial(5));

You can execute this program by running val factorial.val, which will write to standard output 120.

Lastly, you may want to evaluate a val expression and use it within another program. The tool supports executing arbitrary expressions inline using the --expression or -e option:

val -e 'sin(2) * e ^ pi * cos(sum([1, 2, 3]))'
16.481455793912883

n.b. The --expression option and filename argument are mutually exclusive.

This section describes some of the language features val implements in detail, and should serve as a guide to anyone wanting to write a val program.

val supports a few statement constructs such as if, while, loop, fn, return, etc. Check out the grammar for all of the various statement types.

Here's an example showcasing most of them in action:

fn fib(n) {
  if (n <= 1) { return n }
  return fib(n - 1) + fib(n - 2)
}

i = 0

while (i < 10) {
  println('fib(' + i + ') = ' + fib(i))
  i = i + 1
}

val supports a variety of expressions that can be combined to form more complex operations:

val has several primitive value types:

Numeric values are represented as double-precision floating point numbers:

x = 42
y = 3.14159
z = -5

Boolean values represent truth values:

a = true
b = false
c = a && b
d = a || b
e = !a

Text values enclosed in single or double quotes:

greeting = "Hello"
name = 'World'
message = greeting + ", " + name + "!"

Collections of values of any type:

numbers = [1, 2, 3, 4, 5]
mixed = [1, "two", true, [3, 4]]
empty = []
first = numbers[0]
numbers[0] = 10
combined = numbers + [6, 7]

A function is a value, and can be used in assignments, passed around to other functions, etc.

Check out the higher order functions example for how this works.

fn reduce(l, f, initial) {
  i = 0

  result = initial

  while (i < len(l)) {
    result = f(result, l[i])
    i = i + 1
  }

  return result
}

fn sum(a, b) {
  return a + b
}

l = [1, 2, 3, 4, 5]

println(reduce(l, sum, 0))

val offers a ton of built-in functions and constants. Below documents them:

bc(1) - An arbitrary precision calculator language